# Script pour la conférence des mercredis de la Physique, 15/12/2004
# Requis: texture haute résolution de la terre 
#     (attention, 1G d'espace disque! http://celestia.h-schmidt.net/earth-vt/
# Jean Orloff <orloff@in2p3.fr>

{
	time { utc "2004-12-15T9:00:00" }
	timerate { rate 1 }
	labels { clear "planets|minorplanets|stars|constellations|moons|galaxies|spacecraft|asteroid" }
	renderflags { set "stars|planets|atmospheres"
                      clear "constellations|orbits|cloudmaps" }
#	print { text "Pret a embarquer . . .\nAppuyer ESC pour arreter." row -3 duration 2 }
#	wait { duration 2.0 }

	select { object "Sol/Earth" }
	synchronous { }
	setsurface { name "Earth 32k Normalmap+Nightlights+Spec" }
	set { name "FOV" value 80.0 }
        gotolonglat { time 0 distance 1.025 longitude 2.96 latitude 45.780 } # Puy-de-Dome
	print { text "Nous voici a la verticale du Puy de Dome; reconnaissez-vous les Cezeaux et le LPC? (&)" row -3 duration 9 }
	wait { duration 10 }

	print { text "Faisons s'ecouler 2 jours 20s: les ombres jouent autour du Sancy et du Cantal..." row -3 duration 5 }
	wait { duration 6 }
	timerate { rate 8640 }
	wait { duration 2 }	
	print { text "... et les lumieres des villes s'allument: Clermont, Lyon, Limoges" row -3 duration 5 }
	wait { duration 18 }
	time { utc "2004-12-15T9:00:00" }
	timerate { rate 1 }

	print { text "Prenons maintenant un peu de champ: passons de 160km a 320km d'altitude..." row -3 duration 5 }
       gotolonglat { time 6 distance 1.05 longitude 2.96 latitude 45.780 }
	wait { duration 6 }

	print { text "puis a 640km d'altitude..." row -3 duration 5 }
        gotolonglat { time 6 distance 1.1 longitude 2.96 latitude 45.780 }
	wait {duration 6 }

	print { text "... a 1200km d'altitude..." row -3 duration 4 }
        gotolonglat { time 6 distance 1.2 longitude 2.96 latitude 45.780 }
	wait {duration 6 }

	print { text "... et a 6400km d'altitude" row -3 duration 14 }
        gotolonglat { time 15 distance 2 longitude 2.96 latitude 45.780 }
	wait { duration 15 }

	timerate { rate 1440 }
	print { text "Nous sommes toujours geostationnaires a la verticale du Puy de Dome; 24h s'ecoulent maintenant en 1 min." row -5 duration 5 }
	wait { duration 6 }

	print { text "Reperons-nous avec les planetes et les constellations," row -3 duration 5 }
	wait { duration 6 }
	labels { set "galaxies|moons|constellations" }
	renderflags { set "constellations" }

	print { text "Le soleil se couche sur Clermont; le ciel que nous voyons derriere ne nous est donc pas familier" row -3 duration 9 }
	wait { duration 10}
	labels { set "planets" }
	print { text "Mars et Venus se levent avant le soleil en ce moment" row -3 duration 5 }
	wait { duration 6.4 }

	timerate { rate 1 }
	select { object "Sol" }
	print { text "Et le soleil..." row -3 duration 3 }
	wait { duration 3 }

	select {object "Milky Way" }
	print { text "...est pratiquement aligne avec le centre galactique (-> voie lactee en hiver?)" row -3 duration 7 }
	wait { duration 7 }
	timerate { rate 1440 }

	select {object "Sol/Earth" }
	print { 
		text "Eloignons-nous de la terre: premier arret: la lune"
		row -3
		duration 5
	}
	goto { distance 100 time 7 }
	wait {duration 3}
	renderflags { set "orbits" }	
	print { 
		text "Visualisons les orbites,"
		row -3
		duration 5
	}
	wait { duration 5}	

	goto { distance 40000 time 7 }
	print { 
		text "avec les planetes internes..."
		row -3
		duration 5
	}
	wait { duration 5 }

	goto { distance 1500000 time 7 }
	print { 
		text "... et le systeme solaire entier"
		row -3
		duration 5
	}
	wait { duration 5 }

}